File Manager

XYZ File Manager

Current Path: /usr/share/cmake/Modules

📁 ..
📄 AddFileDependencies.cmake(955 B)
📁 AndroidTestUtilities
📄 AndroidTestUtilities.cmake(6.22 KB)
📄 BasicConfigVersion-AnyNewerVersion.cmake.in(1.4 KB)
📄 BasicConfigVersion-ExactVersion.cmake.in(2.78 KB)
📄 BasicConfigVersion-SameMajorVersion.cmake.in(2.3 KB)
📄 BasicConfigVersion-SameMinorVersion.cmake.in(3.19 KB)
📄 BundleUtilities.cmake(40.92 KB)
📄 CMake.cmake(307 B)
📄 CMakeASM-ATTInformation.cmake(566 B)
📄 CMakeASMCompiler.cmake.in(942 B)
📄 CMakeASMInformation.cmake(3.93 KB)
📄 CMakeASM_MARMASMInformation.cmake(1.19 KB)
📄 CMakeASM_MASMInformation.cmake(1.18 KB)
📄 CMakeASM_NASMInformation.cmake(1.96 KB)
📁 CMakeAddFortranSubdirectory
📄 CMakeAddFortranSubdirectory.cmake(7.13 KB)
📄 CMakeAddNewLanguage.txt(1.49 KB)
📄 CMakeBackwardCompatibilityC.cmake(2.54 KB)
📄 CMakeBackwardCompatibilityCXX.cmake(1.77 KB)
📄 CMakeBorlandFindMake.cmake(271 B)
📄 CMakeBuildSettings.cmake.in(681 B)
📄 CMakeCCompiler.cmake.in(2.96 KB)
📄 CMakeCCompilerABI.c(511 B)
📄 CMakeCCompilerId.c.in(2.76 KB)
📄 CMakeCInformation.cmake(6.74 KB)
📄 CMakeCSharpCompiler.cmake.in(477 B)
📄 CMakeCSharpCompilerId.cs.in(1.59 KB)
📄 CMakeCSharpInformation.cmake(2.94 KB)
📄 CMakeCUDACompiler.cmake.in(3.56 KB)
📄 CMakeCUDACompilerABI.cu(1.12 KB)
📄 CMakeCUDACompilerId.cu.in(1.64 KB)
📄 CMakeCUDAInformation.cmake(8.1 KB)
📄 CMakeCXXCompiler.cmake.in(3.52 KB)
📄 CMakeCXXCompilerABI.cpp(388 B)
📄 CMakeCXXCompilerId.cpp.in(2.76 KB)
📄 CMakeCXXInformation.cmake(9.96 KB)
📄 CMakeCheckCompilerFlagCommonPatterns.cmake(2.1 KB)
📄 CMakeCommonLanguageInclude.cmake(1.12 KB)
📄 CMakeCompilerABI.h(1.54 KB)
📄 CMakeCompilerIdDetection.cmake(4.76 KB)
📄 CMakeConfigurableFile.in(34 B)
📄 CMakeDependentOption.cmake(3.08 KB)
📄 CMakeDetermineASM-ATTCompiler.cmake(394 B)
📄 CMakeDetermineASMCompiler.cmake(11.36 KB)
📄 CMakeDetermineASM_MARMASMCompiler.cmake(612 B)
📄 CMakeDetermineASM_MASMCompiler.cmake(586 B)
📄 CMakeDetermineASM_NASMCompiler.cmake(937 B)
📄 CMakeDetermineCCompiler.cmake(8.38 KB)
📄 CMakeDetermineCSharpCompiler.cmake(1.64 KB)
📄 CMakeDetermineCUDACompiler.cmake(28.37 KB)
📄 CMakeDetermineCXXCompiler.cmake(8.76 KB)
📄 CMakeDetermineCompileFeatures.cmake(10.05 KB)
📄 CMakeDetermineCompiler.cmake(7.13 KB)
📄 CMakeDetermineCompilerABI.cmake(8.15 KB)
📄 CMakeDetermineCompilerId.cmake(49.27 KB)
📄 CMakeDetermineFortranCompiler.cmake(11.63 KB)
📄 CMakeDetermineHIPCompiler.cmake(6.89 KB)
📄 CMakeDetermineISPCCompiler.cmake(2.97 KB)
📄 CMakeDetermineJavaCompiler.cmake(3.67 KB)
📄 CMakeDetermineOBJCCompiler.cmake(7.28 KB)
📄 CMakeDetermineOBJCXXCompiler.cmake(7.65 KB)
📄 CMakeDetermineRCCompiler.cmake(2.23 KB)
📄 CMakeDetermineSwiftCompiler.cmake(5.72 KB)
📄 CMakeDetermineSystem.cmake(8.79 KB)
📄 CMakeDetermineVSServicePack.cmake(5.85 KB)
📄 CMakeExpandImportedTargets.cmake(5.95 KB)
📄 CMakeExportBuildSettings.cmake(1.21 KB)
📄 CMakeExtraGeneratorDetermineCompilerMacrosAndIncludeDirs.cmake(5.2 KB)
📄 CMakeFindBinUtils.cmake(10.31 KB)
📄 CMakeFindCodeBlocks.cmake(1.72 KB)
📄 CMakeFindDependencyMacro.cmake(3.76 KB)
📄 CMakeFindEclipseCDT4.cmake(4.84 KB)
📄 CMakeFindFrameworks.cmake(1.8 KB)
📄 CMakeFindJavaCommon.cmake(1.04 KB)
📄 CMakeFindKate.cmake(1.02 KB)
📄 CMakeFindPackageMode.cmake(6.1 KB)
📄 CMakeFindSublimeText2.cmake(1.01 KB)
📄 CMakeFindWMake.cmake(272 B)
📄 CMakeFindXCode.cmake(250 B)
📄 CMakeForceCompiler.cmake(4.11 KB)
📄 CMakeFortranCompiler.cmake.in(2.71 KB)
📄 CMakeFortranCompilerABI.F(1.09 KB)
📄 CMakeFortranCompilerABI.F90(1.08 KB)
📄 CMakeFortranCompilerId.F.in(10.45 KB)
📄 CMakeFortranInformation.cmake(8.82 KB)
📄 CMakeGenericSystem.cmake(7.33 KB)
📄 CMakeGraphVizOptions.cmake(3.73 KB)
📄 CMakeHIPCompiler.cmake.in(2.57 KB)
📄 CMakeHIPCompilerABI.hip(293 B)
📄 CMakeHIPCompilerId.hip.in(1.6 KB)
📄 CMakeHIPInformation.cmake(5.52 KB)
📄 CMakeIOSInstallCombined.cmake(10.2 KB)
📄 CMakeISPCCompiler.cmake.in(1.15 KB)
📄 CMakeISPCCompilerABI.ispc(545 B)
📄 CMakeISPCCompilerId.ispc.in(2.09 KB)
📄 CMakeISPCInformation.cmake(2.35 KB)
📄 CMakeImportBuildSettings.cmake(535 B)
📄 CMakeInitializeConfigs.cmake(1.54 KB)
📄 CMakeJOMFindMake.cmake(270 B)
📄 CMakeJavaCompiler.cmake.in(538 B)
📄 CMakeJavaInformation.cmake(1.74 KB)
📄 CMakeLanguageInformation.cmake(1.23 KB)
📄 CMakeMSYSFindMake.cmake(608 B)
📄 CMakeMinGWFindMake.cmake(437 B)
📄 CMakeNMakeFindMake.cmake(272 B)
📄 CMakeNinjaFindMake.cmake(315 B)
📄 CMakeOBJCCompiler.cmake.in(3.16 KB)
📄 CMakeOBJCCompilerABI.m(556 B)
📄 CMakeOBJCCompilerId.m.in(2.06 KB)
📄 CMakeOBJCInformation.cmake(7.1 KB)
📄 CMakeOBJCXXCompiler.cmake.in(3.64 KB)
📄 CMakeOBJCXXCompilerABI.mm(557 B)
📄 CMakeOBJCXXCompilerId.mm.in(2.03 KB)
📄 CMakeOBJCXXInformation.cmake(10.43 KB)
📄 CMakePackageConfigHelpers.cmake(14.13 KB)
📄 CMakeParseArguments.cmake(581 B)
📄 CMakeParseImplicitIncludeInfo.cmake(9.58 KB)
📄 CMakeParseImplicitLinkInfo.cmake(11.59 KB)
📄 CMakeParseLibraryArchitecture.cmake(1.69 KB)
📄 CMakePlatformId.h.in(8.57 KB)
📄 CMakePrintHelpers.cmake(4.7 KB)
📄 CMakePrintSystemInformation.cmake(2.14 KB)
📄 CMakePushCheckState.cmake(3.85 KB)
📄 CMakeRCCompiler.cmake.in(270 B)
📄 CMakeRCInformation.cmake(1.94 KB)
📄 CMakeSwiftCompiler.cmake.in(717 B)
📄 CMakeSwiftInformation.cmake(6.57 KB)
📄 CMakeSystem.cmake.in(563 B)
📄 CMakeSystemSpecificInformation.cmake(3.03 KB)
📄 CMakeSystemSpecificInitialize.cmake(1 KB)
📄 CMakeTestASM-ATTCompiler.cmake(527 B)
📄 CMakeTestASMCompiler.cmake(865 B)
📄 CMakeTestASM_MARMASMCompiler.cmake(568 B)
📄 CMakeTestASM_MASMCompiler.cmake(556 B)
📄 CMakeTestASM_NASMCompiler.cmake(529 B)
📄 CMakeTestCCompiler.cmake(3.51 KB)
📄 CMakeTestCSharpCompiler.cmake(2.42 KB)
📄 CMakeTestCUDACompiler.cmake(5.64 KB)
📄 CMakeTestCXXCompiler.cmake(3.41 KB)
📄 CMakeTestCompilerCommon.cmake(1.3 KB)
📄 CMakeTestFortranCompiler.cmake(3.92 KB)
📄 CMakeTestGNU.c(268 B)
📄 CMakeTestHIPCompiler.cmake(3.57 KB)
📄 CMakeTestISPCCompiler.cmake(1.42 KB)
📄 CMakeTestJavaCompiler.cmake(484 B)
📄 CMakeTestOBJCCompiler.cmake(3.61 KB)
📄 CMakeTestOBJCXXCompiler.cmake(3.64 KB)
📄 CMakeTestRCCompiler.cmake(573 B)
📄 CMakeTestSwiftCompiler.cmake(2.5 KB)
📄 CMakeUnixFindMake.cmake(575 B)
📄 CMakeVerifyManifest.cmake(3.88 KB)
📄 CPack.cmake(37.04 KB)
📄 CPackComponent.cmake(20.37 KB)
📄 CPackIFW.cmake(26.02 KB)
📄 CPackIFWConfigureFile.cmake(2.21 KB)
📄 CSharpUtilities.cmake(10.73 KB)
📄 CTest.cmake(9 KB)
📄 CTestCoverageCollectGCOV.cmake(11.98 KB)
📄 CTestScriptMode.cmake(662 B)
📄 CTestTargets.cmake(3.12 KB)
📄 CTestUseLaunchers.cmake(2.97 KB)
📁 CUDA
📄 CheckCCompilerFlag.cmake(1.5 KB)
📄 CheckCSourceCompiles.cmake(3.24 KB)
📄 CheckCSourceRuns.cmake(3.19 KB)
📄 CheckCXXCompilerFlag.cmake(1.53 KB)
📄 CheckCXXSourceCompiles.cmake(3.26 KB)
📄 CheckCXXSourceRuns.cmake(3.21 KB)
📄 CheckCXXSymbolExists.cmake(3.03 KB)
📄 CheckCompilerFlag.cmake(1.51 KB)
📄 CheckForPthreads.c(273 B)
📄 CheckFortranCompilerFlag.cmake(1.59 KB)
📄 CheckFortranFunctionExists.cmake(2.69 KB)
📄 CheckFortranSourceCompiles.cmake(4.11 KB)
📄 CheckFortranSourceRuns.cmake(3.94 KB)
📄 CheckFunctionExists.c(433 B)
📄 CheckFunctionExists.cmake(3.87 KB)
📁 CheckIPOSupported
📄 CheckIPOSupported.cmake(7.38 KB)
📄 CheckIncludeFile.c.in(130 B)
📄 CheckIncludeFile.cmake(4.38 KB)
📄 CheckIncludeFile.cxx.in(65 B)
📄 CheckIncludeFileCXX.cmake(4.41 KB)
📄 CheckIncludeFiles.cmake(5.8 KB)
📄 CheckLanguage.cmake(4.21 KB)
📄 CheckLibraryExists.cmake(3 KB)
📄 CheckLibraryExists.lists.in(298 B)
📄 CheckLinkerFlag.cmake(1.71 KB)
📄 CheckOBJCCompilerFlag.cmake(1.56 KB)
📄 CheckOBJCSourceCompiles.cmake(3.25 KB)
📄 CheckOBJCSourceRuns.cmake(3.21 KB)
📄 CheckOBJCXXCompilerFlag.cmake(1.58 KB)
📄 CheckOBJCXXSourceCompiles.cmake(3.28 KB)
📄 CheckOBJCXXSourceRuns.cmake(3.23 KB)
📄 CheckPIESupported.cmake(5.04 KB)
📄 CheckPrototypeDefinition.c.in(514 B)
📄 CheckPrototypeDefinition.cmake(3.8 KB)
📄 CheckSizeOf.cmake(348 B)
📄 CheckSourceCompiles.cmake(3.81 KB)
📄 CheckSourceRuns.cmake(3.68 KB)
📄 CheckStructHasMember.cmake(2.49 KB)
📄 CheckSymbolExists.cmake(5.75 KB)
📄 CheckTypeSize.c.in(1.21 KB)
📄 CheckTypeSize.cmake(9.6 KB)
📄 CheckTypeSizeMap.cmake.in(31 B)
📄 CheckVariableExists.c(382 B)
📄 CheckVariableExists.cmake(2.49 KB)
📁 Compiler
📁 CompilerId
📄 Dart.cmake(3.74 KB)
📄 DartConfiguration.tcl.in(3.22 KB)
📄 DeployQt4.cmake(12.63 KB)
📄 Documentation.cmake(2.24 KB)
📄 DummyCXXFile.cxx(27 B)
📄 ExternalData.cmake(44.35 KB)
📄 ExternalData_config.cmake.in(355 B)
📁 ExternalProject
📄 ExternalProject.cmake(138.23 KB)
📄 FLTKCompatibility.cmake(170 B)
📄 FeatureSummary.cmake(27.97 KB)
📁 FetchContent
📄 FetchContent.cmake(83.64 KB)
📄 FindALSA.cmake(2.18 KB)
📄 FindASPELL.cmake(1.02 KB)
📄 FindAVIFile.cmake(1.35 KB)
📄 FindArmadillo.cmake(4.98 KB)
📄 FindBISON.cmake(10.75 KB)
📄 FindBLAS.cmake(36.21 KB)
📄 FindBZip2.cmake(3.83 KB)
📄 FindBacktrace.cmake(3.44 KB)
📄 FindBoost.cmake(114.04 KB)
📄 FindBullet.cmake(2.75 KB)
📄 FindCABLE.cmake(2.54 KB)
📁 FindCUDA
📄 FindCUDA.cmake(85.84 KB)
📄 FindCUDAToolkit.cmake(42.94 KB)
📄 FindCURL.cmake(7.25 KB)
📄 FindCVS.cmake(1.94 KB)
📄 FindCoin3D.cmake(2.27 KB)
📄 FindCups.cmake(3.37 KB)
📄 FindCurses.cmake(9.2 KB)
📄 FindCxxTest.cmake(7.56 KB)
📄 FindCygwin.cmake(870 B)
📄 FindDCMTK.cmake(10.26 KB)
📄 FindDart.cmake(949 B)
📄 FindDevIL.cmake(3.78 KB)
📄 FindDoxygen.cmake(42.49 KB)
📄 FindEXPAT.cmake(2.67 KB)
📄 FindEnvModules.cmake(9.73 KB)
📄 FindFLEX.cmake(8.46 KB)
📄 FindFLTK.cmake(10.8 KB)
📄 FindFLTK2.cmake(7.5 KB)
📄 FindFontconfig.cmake(2.89 KB)
📄 FindFreetype.cmake(5.97 KB)
📄 FindGCCXML.cmake(672 B)
📄 FindGDAL.cmake(6.46 KB)
📄 FindGIF.cmake(3.79 KB)
📄 FindGLEW.cmake(11.89 KB)
📄 FindGLU.cmake(554 B)
📄 FindGLUT.cmake(6.99 KB)
📄 FindGSL.cmake(8.88 KB)
📄 FindGTK.cmake(3.79 KB)
📄 FindGTK2.cmake(36.91 KB)
📄 FindGTest.cmake(11.77 KB)
📄 FindGettext.cmake(7.81 KB)
📄 FindGit.cmake(4.06 KB)
📄 FindGnuTLS.cmake(2.44 KB)
📄 FindGnuplot.cmake(1.65 KB)
📄 FindHDF5.cmake(48.74 KB)
📄 FindHSPELL.cmake(1.64 KB)
📄 FindHTMLHelp.cmake(1.43 KB)
📄 FindHg.cmake(3 KB)
📄 FindICU.cmake(15.71 KB)
📄 FindIce.cmake(23.82 KB)
📄 FindIconv.cmake(5.79 KB)
📄 FindIcotool.cmake(1.3 KB)
📄 FindImageMagick.cmake(12.35 KB)
📄 FindIntl.cmake(5.38 KB)
📄 FindJNI.cmake(21.5 KB)
📄 FindJPEG.cmake(4.21 KB)
📄 FindJasper.cmake(2.96 KB)
📄 FindJava.cmake(11.9 KB)
📄 FindKDE3.cmake(9.91 KB)
📄 FindKDE4.cmake(3.12 KB)
📄 FindLAPACK.cmake(21.75 KB)
📄 FindLATEX.cmake(6.5 KB)
📄 FindLTTngUST.cmake(3.61 KB)
📄 FindLibArchive.cmake(2.92 KB)
📄 FindLibLZMA.cmake(5.58 KB)
📄 FindLibXml2.cmake(4.12 KB)
📄 FindLibXslt.cmake(4.75 KB)
📄 FindLibinput.cmake(2.13 KB)
📄 FindLua.cmake(8.24 KB)
📄 FindLua50.cmake(2.34 KB)
📄 FindLua51.cmake(2.23 KB)
📄 FindMFC.cmake(1.86 KB)
📄 FindMPEG.cmake(1.21 KB)
📄 FindMPEG2.cmake(1.39 KB)
📁 FindMPI
📄 FindMPI.cmake(91.49 KB)
📄 FindMatlab.cmake(70.23 KB)
📄 FindMotif.cmake(917 B)
📄 FindMsys.cmake(1.03 KB)
📄 FindODBC.cmake(7.01 KB)
📄 FindOpenACC.cmake(9.99 KB)
📄 FindOpenAL.cmake(3.93 KB)
📄 FindOpenCL.cmake(4.9 KB)
📄 FindOpenGL.cmake(20.19 KB)
📄 FindOpenMP.cmake(26.96 KB)
📄 FindOpenSP.cmake(4.55 KB)
📄 FindOpenSSL.cmake(26.92 KB)
📄 FindOpenSceneGraph.cmake(7.23 KB)
📄 FindOpenThreads.cmake(3.41 KB)
📄 FindPHP4.cmake(2.11 KB)
📄 FindPNG.cmake(5.74 KB)
📄 FindPackageHandleStandardArgs.cmake(22.63 KB)
📄 FindPackageMessage.cmake(1.67 KB)
📄 FindPatch.cmake(1.77 KB)
📄 FindPerl.cmake(2.93 KB)
📄 FindPerlLibs.cmake(5.15 KB)
📄 FindPhysFS.cmake(1.12 KB)
📄 FindPike.cmake(922 B)
📄 FindPkgConfig.cmake(35.91 KB)
📄 FindPostgreSQL.cmake(12.34 KB)
📄 FindProducer.cmake(2.24 KB)
📄 FindProtobuf.cmake(23.4 KB)
📁 FindPython
📄 FindPython.cmake(22.01 KB)
📄 FindPython2.cmake(14.13 KB)
📄 FindPython3.cmake(18.59 KB)
📄 FindPythonInterp.cmake(7.16 KB)
📄 FindPythonLibs.cmake(15.86 KB)
📄 FindQt.cmake(6.31 KB)
📄 FindQt3.cmake(9.46 KB)
📄 FindQt4.cmake(52.42 KB)
📄 FindQuickTime.cmake(1011 B)
📄 FindRTI.cmake(3.22 KB)
📄 FindRuby.cmake(17.37 KB)
📄 FindSDL.cmake(7.92 KB)
📄 FindSDL_gfx.cmake(3.19 KB)
📄 FindSDL_image.cmake(3.65 KB)
📄 FindSDL_mixer.cmake(3.65 KB)
📄 FindSDL_net.cmake(3.47 KB)
📄 FindSDL_sound.cmake(12.35 KB)
📄 FindSDL_ttf.cmake(3.47 KB)
📄 FindSQLite3.cmake(2 KB)
📄 FindSWIG.cmake(5.41 KB)
📄 FindSelfPackers.cmake(1.59 KB)
📄 FindSquish.cmake(9.26 KB)
📄 FindSubversion.cmake(6.24 KB)
📄 FindTCL.cmake(8.05 KB)
📄 FindTIFF.cmake(6.54 KB)
📄 FindTclStub.cmake(4.46 KB)
📄 FindTclsh.cmake(3.6 KB)
📄 FindThreads.cmake(7.4 KB)
📄 FindUnixCommands.cmake(1.58 KB)
📄 FindVulkan.cmake(28.16 KB)
📄 FindWget.cmake(968 B)
📄 FindWish.cmake(2.72 KB)
📄 FindX11.cmake(36.81 KB)
📄 FindXCTest.cmake(7.19 KB)
📄 FindXMLRPC.cmake(3.98 KB)
📄 FindXalanC.cmake(5.85 KB)
📄 FindXercesC.cmake(5.59 KB)
📄 FindZLIB.cmake(7.32 KB)
📄 Findosg.cmake(1.88 KB)
📄 FindosgAnimation.cmake(1.87 KB)
📄 FindosgDB.cmake(1.77 KB)
📄 FindosgFX.cmake(1.76 KB)
📄 FindosgGA.cmake(1.77 KB)
📄 FindosgIntrospection.cmake(1.96 KB)
📄 FindosgManipulator.cmake(1.93 KB)
📄 FindosgParticle.cmake(1.86 KB)
📄 FindosgPresentation.cmake(2.02 KB)
📄 FindosgProducer.cmake(1.87 KB)
📄 FindosgQt.cmake(1.82 KB)
📄 FindosgShadow.cmake(1.83 KB)
📄 FindosgSim.cmake(1.77 KB)
📄 FindosgTerrain.cmake(1.84 KB)
📄 FindosgText.cmake(1.77 KB)
📄 FindosgUtil.cmake(1.78 KB)
📄 FindosgViewer.cmake(1.82 KB)
📄 FindosgVolume.cmake(1.82 KB)
📄 FindosgWidget.cmake(1.87 KB)
📄 Findosg_functions.cmake(2.08 KB)
📄 FindwxWidgets.cmake(41.74 KB)
📄 FindwxWindows.cmake(23.78 KB)
📁 FortranCInterface
📄 FortranCInterface.cmake(14.27 KB)
📄 GNUInstallDirs.cmake(16.9 KB)
📄 GenerateExportHeader.cmake(15.25 KB)
📄 GetPrerequisites.cmake(33.35 KB)
📄 GoogleTest.cmake(23.69 KB)
📄 GoogleTestAddTests.cmake(7.74 KB)
📄 ITKCompatibility.cmake(224 B)
📄 InstallRequiredSystemLibraries.cmake(30.51 KB)
📁 IntelVSImplicitPath
📁 Internal
📄 KDE3Macros.cmake(12.39 KB)
📄 MacOSXBundleInfo.plist.in(1.19 KB)
📄 MacOSXFrameworkInfo.plist.in(886 B)
📄 MacroAddFileDependencies.cmake(848 B)
📄 MatlabTestsRedirect.cmake(3.44 KB)
📁 Platform
📄 ProcessorCount.cmake(8.78 KB)
📄 Qt4ConfigDependentSettings.cmake(7.61 KB)
📄 Qt4Macros.cmake(18.79 KB)
📄 SelectLibraryConfigurations.cmake(3.21 KB)
📄 Squish4RunTestCase.bat(648 B)
📄 Squish4RunTestCase.sh(631 B)
📄 SquishRunTestCase.bat(219 B)
📄 SquishRunTestCase.sh(272 B)
📄 SquishTestScript.cmake(3.41 KB)
📄 SystemInformation.cmake(3.04 KB)
📄 SystemInformation.in(4.59 KB)
📄 TestBigEndian.cmake(4.7 KB)
📄 TestCXXAcceptsFlag.cmake(1013 B)
📄 TestEndianess.c.in(871 B)
📄 TestForANSIForScope.cmake(1.02 KB)
📄 TestForANSIStreamHeaders.cmake(1.04 KB)
📄 TestForANSIStreamHeaders.cxx(60 B)
📄 TestForAnsiForScope.cxx(95 B)
📄 TestForSSTREAM.cmake(1 KB)
📄 TestForSSTREAM.cxx(149 B)
📄 TestForSTDNamespace.cmake(978 B)
📄 TestForSTDNamespace.cxx(75 B)
📄 UseEcos.cmake(9.7 KB)
📁 UseJava
📄 UseJava.cmake(61.86 KB)
📄 UsePkgConfig.cmake(2.65 KB)
📄 UseQt4.cmake(3.62 KB)
📁 UseSWIG
📄 UseSWIG.cmake(41.8 KB)
📄 Use_wxWindows.cmake(2.1 KB)
📄 UsewxWidgets.cmake(1.88 KB)
📄 VTKCompatibility.cmake(1.78 KB)
📄 WriteBasicConfigVersionFile.cmake(2.26 KB)
📄 WriteCompilerDetectionHeader.cmake(30.97 KB)
📄 ecos_clean.cmake(492 B)
📄 exportheader.cmake.in(1.08 KB)
📄 kde3init_dummy.cpp.in(227 B)
📄 kde3uic.cmake(723 B)
📄 readme.txt(233 B)

Editing: FindVulkan.cmake

# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
# file Copyright.txt or https://cmake.org/licensing for details.

#[=======================================================================[.rst:
FindVulkan
----------

.. versionadded:: 3.7

Find Vulkan, which is a low-overhead, cross-platform 3D graphics
and computing API.

Optional COMPONENTS
^^^^^^^^^^^^^^^^^^^

.. versionadded:: 3.24

This module respects several optional COMPONENTS.
There are corresponding imported targets for each of these.

``glslc``
  The SPIR-V compiler.

``glslangValidator``
  The ``glslangValidator`` tool.

``glslang``
  The SPIR-V generator library.

``shaderc_combined``
  The static library for Vulkan shader compilation.

``SPIRV-Tools``
  Tools to process SPIR-V modules.

``MoltenVK``
  On macOS, an additional component ``MoltenVK`` is available.

``dxc``
  .. versionadded:: 3.25

The DirectX Shader Compiler.

The ``glslc`` and ``glslangValidator`` components are provided even
if not explicitly requested (for backward compatibility).

IMPORTED Targets
^^^^^^^^^^^^^^^^

This module defines :prop_tgt:`IMPORTED` targets if Vulkan has been found:

``Vulkan::Vulkan``
  The main Vulkan library.

``Vulkan::glslc``
  .. versionadded:: 3.19

The GLSLC SPIR-V compiler, if it has been found.

``Vulkan::Headers``
  .. versionadded:: 3.21

Provides just Vulkan headers include paths, if found.  No library is
  included in this target.  This can be useful for applications that
  load Vulkan library dynamically.

``Vulkan::glslangValidator``
  .. versionadded:: 3.21

The glslangValidator tool, if found.  It is used to compile GLSL and
  HLSL shaders into SPIR-V.

``Vulkan::glslang``
  .. versionadded:: 3.24

Defined if SDK has the Khronos-reference front-end shader parser and SPIR-V
  generator library (glslang).

``Vulkan::shaderc_combined``
  .. versionadded:: 3.24

Defined if SDK has the Google static library for Vulkan shader compilation
  (shaderc_combined).

``Vulkan::SPIRV-Tools``
  .. versionadded:: 3.24

Defined if SDK has the Khronos library to process SPIR-V modules
  (SPIRV-Tools).

``Vulkan::MoltenVK``
  .. versionadded:: 3.24

Defined if SDK has the Khronos library which implement a subset of Vulkan API
  over Apple Metal graphics framework. (MoltenVK).

``Vulkan::volk``
  .. versionadded:: 3.25

Defined if SDK has the Vulkan meta-loader (volk).

``Vulkan::dxc_lib``
  .. versionadded:: 3.25

Defined if SDK has the DirectX shader compiler library.

``Vulkan::dxc_exe``
  .. versionadded:: 3.25

Defined if SDK has the DirectX shader compiler CLI tool.

Result Variables
^^^^^^^^^^^^^^^^

This module defines the following variables:

``Vulkan_FOUND``
  set to true if Vulkan was found
``Vulkan_INCLUDE_DIRS``
  include directories for Vulkan
``Vulkan_LIBRARIES``
  link against this library to use Vulkan
``Vulkan_VERSION``
  .. versionadded:: 3.23

value from ``vulkan/vulkan_core.h``
``Vulkan_glslc_FOUND``
  .. versionadded:: 3.24

True, if the SDK has the glslc executable.
``Vulkan_glslangValidator_FOUND``
  .. versionadded:: 3.24

True, if the SDK has the glslangValidator executable.
``Vulkan_glslang_FOUND``
  .. versionadded:: 3.24

True, if the SDK has the glslang library.
``Vulkan_shaderc_combined_FOUND``
  .. versionadded:: 3.24

True, if the SDK has the shaderc_combined library.
``Vulkan_SPIRV-Tools_FOUND``
  .. versionadded:: 3.24

True, if the SDK has the SPIRV-Tools library.
``Vulkan_MoltenVK_FOUND``
  .. versionadded:: 3.24

True, if the SDK has the MoltenVK library.
``Vulkan_volk_FOUND``
  .. versionadded:: 3.25

True, if the SDK has the volk library.

``Vulkan_dxc_lib_FOUND``
  .. versionadded:: 3.25

True, if the SDK has the DirectX shader compiler library.

``Vulkan_dxc_exe_FOUND``
  .. versionadded:: 3.25

True, if the SDK has the DirectX shader compiler CLI tool.

The module will also defines these cache variables:

``Vulkan_INCLUDE_DIR``
  the Vulkan include directory
``Vulkan_LIBRARY``
  the path to the Vulkan library
``Vulkan_GLSLC_EXECUTABLE``
  the path to the GLSL SPIR-V compiler
``Vulkan_GLSLANG_VALIDATOR_EXECUTABLE``
  the path to the glslangValidator tool
``Vulkan_glslang_LIBRARY``
  .. versionadded:: 3.24

Path to the glslang library.
``Vulkan_shaderc_combined_LIBRARY``
  .. versionadded:: 3.24

Path to the shaderc_combined library.
``Vulkan_SPIRV-Tools_LIBRARY``
  .. versionadded:: 3.24

Path to the SPIRV-Tools library.
``Vulkan_MoltenVK_LIBRARY``
  .. versionadded:: 3.24

Path to the MoltenVK library.

``Vulkan_volk_LIBRARY``
  .. versionadded:: 3.25

Path to the volk library.

``Vulkan_dxc_LIBRARY``
  .. versionadded:: 3.25

Path to the DirectX shader compiler library.

``Vulkan_dxc_EXECUTABLE``
  .. versionadded:: 3.25

Path to the DirectX shader compiler CLI tool.

Hints
^^^^^

.. versionadded:: 3.18

The ``VULKAN_SDK`` environment variable optionally specifies the
location of the Vulkan SDK root directory for the given
architecture. It is typically set by sourcing the toplevel
``setup-env.sh`` script of the Vulkan SDK directory into the shell
environment.

#]=======================================================================]

cmake_policy(PUSH)
cmake_policy(SET CMP0057 NEW)

# Provide compatibility with a common invalid component request that
# was silently ignored prior to CMake 3.24.
if("FATAL_ERROR" IN_LIST Vulkan_FIND_COMPONENTS)
  message(AUTHOR_WARNING
    "Ignoring unknown component 'FATAL_ERROR'.\n"
    "The find_package() command documents no such argument."
    )
  list(REMOVE_ITEM Vulkan_FIND_COMPONENTS "FATAL_ERROR")
endif()

# For backward compatibility as `FindVulkan` in previous CMake versions allow to retrieve `glslc`
# and `glslangValidator` without requesting the corresponding component.
if(NOT glslc IN_LIST Vulkan_FIND_COMPONENTS)
  list(APPEND Vulkan_FIND_COMPONENTS glslc)
endif()
if(NOT glslangValidator IN_LIST Vulkan_FIND_COMPONENTS)
  list(APPEND Vulkan_FIND_COMPONENTS glslangValidator)
endif()

if(WIN32)
  set(_Vulkan_library_name vulkan-1)
  set(_Vulkan_hint_include_search_paths
    "$ENV{VULKAN_SDK}/Include"
  )
  if(CMAKE_SIZEOF_VOID_P EQUAL 8)
    set(_Vulkan_hint_executable_search_paths
      "$ENV{VULKAN_SDK}/Bin"
    )
    set(_Vulkan_hint_library_search_paths
      "$ENV{VULKAN_SDK}/Lib"
      "$ENV{VULKAN_SDK}/Bin"
    )
  else()
    set(_Vulkan_hint_executable_search_paths
      "$ENV{VULKAN_SDK}/Bin32"
    )
    set(_Vulkan_hint_library_search_paths
      "$ENV{VULKAN_SDK}/Lib32"
      "$ENV{VULKAN_SDK}/Bin32"
    )
  endif()
else()
  set(_Vulkan_library_name vulkan)
  set(_Vulkan_hint_include_search_paths
    "$ENV{VULKAN_SDK}/include"
  )
  set(_Vulkan_hint_executable_search_paths
    "$ENV{VULKAN_SDK}/bin"
  )
  set(_Vulkan_hint_library_search_paths
    "$ENV{VULKAN_SDK}/lib"
  )
endif()
if(APPLE AND DEFINED ENV{VULKAN_SDK})
  cmake_path(SET _MoltenVK_path NORMALIZE "$ENV{VULKAN_SDK}/../MoltenVK")
  if(EXISTS "${_MoltenVK_path}")
    list(APPEND _Vulkan_hint_include_search_paths
      "${_MoltenVK_path}/include"
    )
    if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
      list(APPEND _Vulkan_hint_library_search_paths
        "${_MoltenVK_path}/dylib/iOS"
      )
    elseif(CMAKE_SYSTEM_NAME STREQUAL "tvOS")
      list(APPEND _Vulkan_hint_library_search_paths
        "${_MoltenVK_path}/dylib/tvOS"
      )
    else()
      list(APPEND _Vulkan_hint_library_search_paths
        "${_MoltenVK_path}/dylib/macOS"
      )
    endif()
  endif()
  unset(_MoltenVK_path)
endif()

find_path(Vulkan_INCLUDE_DIR
  NAMES vulkan/vulkan.h
  HINTS
    ${_Vulkan_hint_include_search_paths}
  )
mark_as_advanced(Vulkan_INCLUDE_DIR)

find_library(Vulkan_LIBRARY
  NAMES ${_Vulkan_library_name}
  HINTS
    ${_Vulkan_hint_library_search_paths}
  )
mark_as_advanced(Vulkan_LIBRARY)

if(glslc IN_LIST Vulkan_FIND_COMPONENTS)
  find_program(Vulkan_GLSLC_EXECUTABLE
    NAMES glslc
    HINTS
      ${_Vulkan_hint_executable_search_paths}
    )
  mark_as_advanced(Vulkan_GLSLC_EXECUTABLE)
endif()
if(glslangValidator IN_LIST Vulkan_FIND_COMPONENTS)
  find_program(Vulkan_GLSLANG_VALIDATOR_EXECUTABLE
    NAMES glslangValidator
    HINTS
      ${_Vulkan_hint_executable_search_paths}
    )
  mark_as_advanced(Vulkan_GLSLANG_VALIDATOR_EXECUTABLE)
endif()
if(glslang IN_LIST Vulkan_FIND_COMPONENTS)
  find_library(Vulkan_glslang-spirv_LIBRARY
    NAMES SPIRV
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-spirv_LIBRARY)

find_library(Vulkan_glslang-spirv_DEBUG_LIBRARY
    NAMES SPIRVd
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-spirv_DEBUG_LIBRARY)

find_library(Vulkan_glslang-oglcompiler_LIBRARY
    NAMES OGLCompiler
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-oglcompiler_LIBRARY)

find_library(Vulkan_glslang-oglcompiler_DEBUG_LIBRARY
    NAMES OGLCompilerd
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-oglcompiler_DEBUG_LIBRARY)

find_library(Vulkan_glslang-osdependent_LIBRARY
    NAMES OSDependent
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-osdependent_LIBRARY)

find_library(Vulkan_glslang-osdependent_DEBUG_LIBRARY
    NAMES OSDependentd
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-osdependent_DEBUG_LIBRARY)

find_library(Vulkan_glslang-machineindependent_LIBRARY
    NAMES MachineIndependent
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-machineindependent_LIBRARY)

find_library(Vulkan_glslang-machineindependent_DEBUG_LIBRARY
    NAMES MachineIndependentd
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-machineindependent_DEBUG_LIBRARY)

find_library(Vulkan_glslang-genericcodegen_LIBRARY
    NAMES GenericCodeGen
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-genericcodegen_LIBRARY)

find_library(Vulkan_glslang-genericcodegen_DEBUG_LIBRARY
    NAMES GenericCodeGend
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang-genericcodegen_DEBUG_LIBRARY)

find_library(Vulkan_glslang_LIBRARY
    NAMES glslang
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang_LIBRARY)

find_library(Vulkan_glslang_DEBUG_LIBRARY
    NAMES glslangd
    HINTS
      ${_Vulkan_hint_library_search_paths}
    )
  mark_as_advanced(Vulkan_glslang_DEBUG_LIBRARY)
endif()
if(shaderc_combined IN_LIST Vulkan_FIND_COMPONENTS)
  find_library(Vulkan_shaderc_combined_LIBRARY
    NAMES shaderc_combined
    HINTS
    ${_Vulkan_hint_library_search_paths})
  mark_as_advanced(Vulkan_shaderc_combined_LIBRARY)

find_library(Vulkan_shaderc_combined_DEBUG_LIBRARY
    NAMES shaderc_combinedd
    HINTS
    ${_Vulkan_hint_library_search_paths})
  mark_as_advanced(Vulkan_shaderc_combined_DEBUG_LIBRARY)
endif()
if(SPIRV-Tools IN_LIST Vulkan_FIND_COMPONENTS)
  find_library(Vulkan_SPIRV-Tools_LIBRARY
    NAMES SPIRV-Tools
    HINTS
      ${_Vulkan_hint_library_search_paths})
  mark_as_advanced(Vulkan_SPIRV-Tools_LIBRARY)

find_library(Vulkan_SPIRV-Tools_DEBUG_LIBRARY
    NAMES SPIRV-Toolsd
    HINTS
      ${_Vulkan_hint_library_search_paths})
  mark_as_advanced(Vulkan_SPIRV-Tools_DEBUG_LIBRARY)
endif()
if(MoltenVK IN_LIST Vulkan_FIND_COMPONENTS)
  find_library(Vulkan_MoltenVK_LIBRARY
    NAMES MoltenVK
    HINTS
      ${_Vulkan_hint_library_search_paths})
  mark_as_advanced(Vulkan_MoltenVK_LIBRARY)

find_path(Vulkan_MoltenVK_INCLUDE_DIR
    NAMES MoltenVK/mvk_vulkan.h
    HINTS
      ${_Vulkan_hint_include_search_paths}
    )
  mark_as_advanced(Vulkan_MoltenVK_INCLUDE_DIR)
endif()
if(volk IN_LIST Vulkan_FIND_COMPONENTS)
  find_library(Vulkan_volk_LIBRARY
          NAMES volk
          HINTS
            ${_Vulkan_hint_library_search_paths})
  mark_as_advanced(Vulkan_Volk_LIBRARY)
endif()

if (dxc IN_LIST Vulkan_FIND_COMPONENTS)
  find_library(Vulkan_dxc_LIBRARY
          NAMES dxcompiler
          HINTS
            ${_Vulkan_hint_library_search_paths})
  mark_as_advanced(Vulkan_dxc_LIBRARY)

find_program(Vulkan_dxc_EXECUTABLE
          NAMES dxc
          HINTS
            ${_Vulkan_hint_executable_search_paths})
  mark_as_advanced(Vulkan_dxc_EXECUTABLE)
endif()

if(Vulkan_GLSLC_EXECUTABLE)
  set(Vulkan_glslc_FOUND TRUE)
else()
  set(Vulkan_glslc_FOUND FALSE)
endif()

if(Vulkan_GLSLANG_VALIDATOR_EXECUTABLE)
  set(Vulkan_glslangValidator_FOUND TRUE)
else()
  set(Vulkan_glslangValidator_FOUND FALSE)
endif()

if (Vulkan_dxc_EXECUTABLE)
  set(Vulkan_dxc_exe_FOUND TRUE)
else()
  set(Vulkan_dxc_exe_FOUND FALSE)
endif()

function(_Vulkan_set_library_component_found component)
  cmake_parse_arguments(PARSE_ARGV 1 _ARG
    "NO_WARNING"
    ""
    "DEPENDENT_COMPONENTS")

set(all_dependent_component_found TRUE)
  foreach(dependent_component IN LISTS _ARG_DEPENDENT_COMPONENTS)
    if(NOT Vulkan_${dependent_component}_FOUND)
      set(all_dependent_component_found FALSE)
      break()
    endif()
  endforeach()

if(all_dependent_component_found AND (Vulkan_${component}_LIBRARY OR Vulkan_${component}_DEBUG_LIBRARY))
    set(Vulkan_${component}_FOUND TRUE PARENT_SCOPE)

# For Windows Vulkan SDK, third party tools binaries are provided with different MSVC ABI:
    #   - Release binaries uses a runtime library
    #   - Debug binaries uses a debug runtime library
    # This lead to incompatibilities in linking for some configuration types due to CMake-default or project-configured selected MSVC ABI.
    if(WIN32 AND NOT _ARG_NO_WARNING)
      if(NOT Vulkan_${component}_LIBRARY)
        message(WARNING
"Library ${component} for Release configuration is missing, imported target Vulkan::${component} may not be able to link when targeting this build configuration due to incompatible MSVC ABI.")
      endif()
      if(NOT Vulkan_${component}_DEBUG_LIBRARY)
        message(WARNING
"Library ${component} for Debug configuration is missing, imported target Vulkan::${component} may not be able to link when targeting this build configuration due to incompatible MSVC ABI. Consider re-installing the Vulkan SDK and request debug libraries to fix this warning.")
      endif()
    endif()
  else()
    set(Vulkan_${component}_FOUND FALSE PARENT_SCOPE)
  endif()
endfunction()

_Vulkan_set_library_component_found(glslang-spirv NO_WARNING)
_Vulkan_set_library_component_found(glslang-oglcompiler NO_WARNING)
_Vulkan_set_library_component_found(glslang-osdependent NO_WARNING)
_Vulkan_set_library_component_found(glslang-machineindependent NO_WARNING)
_Vulkan_set_library_component_found(glslang-genericcodegen NO_WARNING)
_Vulkan_set_library_component_found(glslang
  DEPENDENT_COMPONENTS
    glslang-spirv
    glslang-oglcompiler
    glslang-osdependent
    glslang-machineindependent
    glslang-genericcodegen)
_Vulkan_set_library_component_found(shaderc_combined)
_Vulkan_set_library_component_found(SPIRV-Tools)
_Vulkan_set_library_component_found(volk)
_Vulkan_set_library_component_found(dxc)

if(Vulkan_MoltenVK_INCLUDE_DIR AND Vulkan_MoltenVK_LIBRARY)
  set(Vulkan_MoltenVK_FOUND TRUE)
else()
  set(Vulkan_MoltenVK_FOUND FALSE)
endif()

set(Vulkan_LIBRARIES ${Vulkan_LIBRARY})
set(Vulkan_INCLUDE_DIRS ${Vulkan_INCLUDE_DIR})

# detect version e.g 1.2.189
set(Vulkan_VERSION "")
if(Vulkan_INCLUDE_DIR)
  set(VULKAN_CORE_H ${Vulkan_INCLUDE_DIR}/vulkan/vulkan_core.h)
  if(EXISTS ${VULKAN_CORE_H})
    file(STRINGS  ${VULKAN_CORE_H} VulkanHeaderVersionLine REGEX "^#define VK_HEADER_VERSION ")
    string(REGEX MATCHALL "[0-9]+" VulkanHeaderVersion "${VulkanHeaderVersionLine}")
    file(STRINGS  ${VULKAN_CORE_H} VulkanHeaderVersionLine2 REGEX "^#define VK_HEADER_VERSION_COMPLETE ")
    string(REGEX MATCHALL "[0-9]+" VulkanHeaderVersion2 "${VulkanHeaderVersionLine2}")
    list(LENGTH VulkanHeaderVersion2 _len)
    #  versions >= 1.2.175 have an additional numbers in front of e.g. '0, 1, 2' instead of '1, 2'
    if(_len EQUAL 3)
        list(REMOVE_AT VulkanHeaderVersion2 0)
    endif()
    list(APPEND VulkanHeaderVersion2 ${VulkanHeaderVersion})
    list(JOIN VulkanHeaderVersion2 "." Vulkan_VERSION)
  endif()
endif()

if(Vulkan_MoltenVK_FOUND)
  set(Vulkan_MoltenVK_VERSION "")
  if(Vulkan_MoltenVK_INCLUDE_DIR)
    set(VK_MVK_MOLTENVK_H ${Vulkan_MoltenVK_INCLUDE_DIR}/MoltenVK/vk_mvk_moltenvk.h)
    if(EXISTS ${VK_MVK_MOLTENVK_H})
      file(STRINGS  ${VK_MVK_MOLTENVK_H} _Vulkan_MoltenVK_VERSION_MAJOR REGEX "^#define MVK_VERSION_MAJOR ")
      string(REGEX MATCHALL "[0-9]+" _Vulkan_MoltenVK_VERSION_MAJOR "${_Vulkan_MoltenVK_VERSION_MAJOR}")
      file(STRINGS  ${VK_MVK_MOLTENVK_H} _Vulkan_MoltenVK_VERSION_MINOR REGEX "^#define MVK_VERSION_MINOR ")
      string(REGEX MATCHALL "[0-9]+" _Vulkan_MoltenVK_VERSION_MINOR "${_Vulkan_MoltenVK_VERSION_MINOR}")
      file(STRINGS  ${VK_MVK_MOLTENVK_H} _Vulkan_MoltenVK_VERSION_PATCH REGEX "^#define MVK_VERSION_PATCH ")
      string(REGEX MATCHALL "[0-9]+" _Vulkan_MoltenVK_VERSION_PATCH "${_Vulkan_MoltenVK_VERSION_PATCH}")
      set(Vulkan_MoltenVK_VERSION "${_Vulkan_MoltenVK_VERSION_MAJOR}.${_Vulkan_MoltenVK_VERSION_MINOR}.${_Vulkan_MoltenVK_VERSION_PATCH}")
      unset(_Vulkan_MoltenVK_VERSION_MAJOR)
      unset(_Vulkan_MoltenVK_VERSION_MINOR)
      unset(_Vulkan_MoltenVK_VERSION_PATCH)
    endif()
  endif()
endif()

include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
find_package_handle_standard_args(Vulkan
  REQUIRED_VARS
    Vulkan_LIBRARY
    Vulkan_INCLUDE_DIR
  VERSION_VAR
    Vulkan_VERSION
  HANDLE_COMPONENTS
)

if(Vulkan_FOUND AND NOT TARGET Vulkan::Vulkan)
  add_library(Vulkan::Vulkan UNKNOWN IMPORTED)
  set_target_properties(Vulkan::Vulkan PROPERTIES
    IMPORTED_LOCATION "${Vulkan_LIBRARIES}"
    INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
endif()

if(Vulkan_FOUND AND NOT TARGET Vulkan::Headers)
  add_library(Vulkan::Headers INTERFACE IMPORTED)
  set_target_properties(Vulkan::Headers PROPERTIES
    INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
endif()

if(Vulkan_FOUND AND Vulkan_GLSLC_EXECUTABLE AND NOT TARGET Vulkan::glslc)
  add_executable(Vulkan::glslc IMPORTED)
  set_property(TARGET Vulkan::glslc PROPERTY IMPORTED_LOCATION "${Vulkan_GLSLC_EXECUTABLE}")
endif()

if(Vulkan_FOUND AND Vulkan_GLSLANG_VALIDATOR_EXECUTABLE AND NOT TARGET Vulkan::glslangValidator)
  add_executable(Vulkan::glslangValidator IMPORTED)
  set_property(TARGET Vulkan::glslangValidator PROPERTY IMPORTED_LOCATION "${Vulkan_GLSLANG_VALIDATOR_EXECUTABLE}")
endif()

if(Vulkan_FOUND)
  if((Vulkan_glslang-spirv_LIBRARY OR Vulkan_glslang-spirv_DEBUG_LIBRARY) AND NOT TARGET Vulkan::glslang-spirv)
    add_library(Vulkan::glslang-spirv STATIC IMPORTED)
    set_property(TARGET Vulkan::glslang-spirv
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    if(Vulkan_glslang-spirv_LIBRARY)
      set_property(TARGET Vulkan::glslang-spirv APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Release)
      set_property(TARGET Vulkan::glslang-spirv
        PROPERTY
          IMPORTED_LOCATION_RELEASE "${Vulkan_glslang-spirv_LIBRARY}")
    endif()
    if(Vulkan_glslang-spirv_DEBUG_LIBRARY)
      set_property(TARGET Vulkan::glslang-spirv APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Debug)
      set_property(TARGET Vulkan::glslang-spirv
        PROPERTY
          IMPORTED_LOCATION_DEBUG "${Vulkan_glslang-spirv_DEBUG_LIBRARY}")
    endif()
  endif()

if((Vulkan_glslang-oglcompiler_LIBRARY OR Vulkan_glslang-oglcompiler_DEBUG_LIBRARY) AND NOT TARGET Vulkan::glslang-oglcompiler)
    add_library(Vulkan::glslang-oglcompiler STATIC IMPORTED)
    set_property(TARGET Vulkan::glslang-oglcompiler
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    if(Vulkan_glslang-oglcompiler_LIBRARY)
      set_property(TARGET Vulkan::glslang-oglcompiler APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Release)
      set_property(TARGET Vulkan::glslang-oglcompiler
        PROPERTY
          IMPORTED_LOCATION_RELEASE "${Vulkan_glslang-oglcompiler_LIBRARY}")
    endif()
    if(Vulkan_glslang-oglcompiler_DEBUG_LIBRARY)
      set_property(TARGET Vulkan::glslang-oglcompiler APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Debug)
      set_property(TARGET Vulkan::glslang-oglcompiler
        PROPERTY
          IMPORTED_LOCATION_DEBUG "${Vulkan_glslang-oglcompiler_DEBUG_LIBRARY}")
    endif()
  endif()

if((Vulkan_glslang-osdependent_LIBRARY OR Vulkan_glslang-osdependent_DEBUG_LIBRARY) AND NOT TARGET Vulkan::glslang-osdependent)
    add_library(Vulkan::glslang-osdependent STATIC IMPORTED)
    set_property(TARGET Vulkan::glslang-osdependent
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    if(Vulkan_glslang-osdependent_LIBRARY)
      set_property(TARGET Vulkan::glslang-osdependent APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Release)
      set_property(TARGET Vulkan::glslang-osdependent
        PROPERTY
          IMPORTED_LOCATION_RELEASE "${Vulkan_glslang-osdependent_LIBRARY}")
    endif()
    if(Vulkan_glslang-osdependent_DEBUG_LIBRARY)
      set_property(TARGET Vulkan::glslang-osdependent APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Debug)
      set_property(TARGET Vulkan::glslang-osdependent
        PROPERTY
          IMPORTED_LOCATION_DEBUG "${Vulkan_glslang-osdependent_DEBUG_LIBRARY}")
    endif()
  endif()

if((Vulkan_glslang-machineindependent_LIBRARY OR Vulkan_glslang-machineindependent_DEBUG_LIBRARY) AND NOT TARGET Vulkan::glslang-machineindependent)
    add_library(Vulkan::glslang-machineindependent STATIC IMPORTED)
    set_property(TARGET Vulkan::glslang-machineindependent
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    if(Vulkan_glslang-machineindependent_LIBRARY)
      set_property(TARGET Vulkan::glslang-machineindependent APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Release)
      set_property(TARGET Vulkan::glslang-machineindependent
        PROPERTY
          IMPORTED_LOCATION_RELEASE "${Vulkan_glslang-machineindependent_LIBRARY}")
    endif()
    if(Vulkan_glslang-machineindependent_DEBUG_LIBRARY)
      set_property(TARGET Vulkan::glslang-machineindependent APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Debug)
      set_property(TARGET Vulkan::glslang-machineindependent
        PROPERTY
          IMPORTED_LOCATION_DEBUG "${Vulkan_glslang-machineindependent_DEBUG_LIBRARY}")
    endif()
  endif()

if((Vulkan_glslang-genericcodegen_LIBRARY OR Vulkan_glslang-genericcodegen_DEBUG_LIBRARY) AND NOT TARGET Vulkan::glslang-genericcodegen)
    add_library(Vulkan::glslang-genericcodegen STATIC IMPORTED)
    set_property(TARGET Vulkan::glslang-genericcodegen
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    if(Vulkan_glslang-genericcodegen_LIBRARY)
      set_property(TARGET Vulkan::glslang-genericcodegen APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Release)
      set_property(TARGET Vulkan::glslang-genericcodegen
        PROPERTY
          IMPORTED_LOCATION_RELEASE "${Vulkan_glslang-genericcodegen_LIBRARY}")
    endif()
    if(Vulkan_glslang-genericcodegen_DEBUG_LIBRARY)
      set_property(TARGET Vulkan::glslang-genericcodegen APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Debug)
      set_property(TARGET Vulkan::glslang-genericcodegen
        PROPERTY
          IMPORTED_LOCATION_DEBUG "${Vulkan_glslang-genericcodegen_DEBUG_LIBRARY}")
    endif()
  endif()

if((Vulkan_glslang_LIBRARY OR Vulkan_glslang_DEBUG_LIBRARY)
      AND TARGET Vulkan::glslang-spirv
      AND TARGET Vulkan::glslang-oglcompiler
      AND TARGET Vulkan::glslang-osdependent
      AND TARGET Vulkan::glslang-machineindependent
      AND TARGET Vulkan::glslang-genericcodegen
      AND NOT TARGET Vulkan::glslang)
    add_library(Vulkan::glslang STATIC IMPORTED)
    set_property(TARGET Vulkan::glslang
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    if(Vulkan_glslang_LIBRARY)
      set_property(TARGET Vulkan::glslang APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Release)
      set_property(TARGET Vulkan::glslang
        PROPERTY
          IMPORTED_LOCATION_RELEASE "${Vulkan_glslang_LIBRARY}")
    endif()
    if(Vulkan_glslang_DEBUG_LIBRARY)
      set_property(TARGET Vulkan::glslang APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Debug)
      set_property(TARGET Vulkan::glslang
        PROPERTY
          IMPORTED_LOCATION_DEBUG "${Vulkan_glslang_DEBUG_LIBRARY}")
    endif()
    target_link_libraries(Vulkan::glslang
      INTERFACE
        Vulkan::glslang-spirv
        Vulkan::glslang-oglcompiler
        Vulkan::glslang-osdependent
        Vulkan::glslang-machineindependent
        Vulkan::glslang-genericcodegen
    )
  endif()

if((Vulkan_shaderc_combined_LIBRARY OR Vulkan_shaderc_combined_DEBUG_LIBRARY) AND NOT TARGET Vulkan::shaderc_combined)
    add_library(Vulkan::shaderc_combined STATIC IMPORTED)
    set_property(TARGET Vulkan::shaderc_combined
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    if(Vulkan_shaderc_combined_LIBRARY)
      set_property(TARGET Vulkan::shaderc_combined APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Release)
      set_property(TARGET Vulkan::shaderc_combined
        PROPERTY
          IMPORTED_LOCATION_RELEASE "${Vulkan_shaderc_combined_LIBRARY}")
    endif()
    if(Vulkan_shaderc_combined_DEBUG_LIBRARY)
      set_property(TARGET Vulkan::shaderc_combined APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Debug)
      set_property(TARGET Vulkan::shaderc_combined
        PROPERTY
          IMPORTED_LOCATION_DEBUG "${Vulkan_shaderc_combined_DEBUG_LIBRARY}")
    endif()

if(UNIX)
      find_package(Threads REQUIRED)
      target_link_libraries(Vulkan::shaderc_combined
        INTERFACE
          Threads::Threads)
    endif()
  endif()

if((Vulkan_SPIRV-Tools_LIBRARY OR Vulkan_SPIRV-Tools_DEBUG_LIBRARY) AND NOT TARGET Vulkan::SPIRV-Tools)
    add_library(Vulkan::SPIRV-Tools STATIC IMPORTED)
    set_property(TARGET Vulkan::SPIRV-Tools
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    if(Vulkan_SPIRV-Tools_LIBRARY)
      set_property(TARGET Vulkan::SPIRV-Tools APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Release)
      set_property(TARGET Vulkan::SPIRV-Tools
        PROPERTY
          IMPORTED_LOCATION_RELEASE "${Vulkan_SPIRV-Tools_LIBRARY}")
    endif()
    if(Vulkan_SPIRV-Tools_DEBUG_LIBRARY)
      set_property(TARGET Vulkan::SPIRV-Tools APPEND
        PROPERTY
          IMPORTED_CONFIGURATIONS Debug)
      set_property(TARGET Vulkan::SPIRV-Tools
        PROPERTY
          IMPORTED_LOCATION_DEBUG "${Vulkan_SPIRV-Tools_DEBUG_LIBRARY}")
    endif()
  endif()

if(Vulkan_volk_LIBRARY AND NOT TARGET Vulkan::volk)
    add_library(Vulkan::volk STATIC IMPORTED)
    set_property(TARGET Vulkan::volk
            PROPERTY
              INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    set_property(TARGET Vulkan::volk APPEND
            PROPERTY
              IMPORTED_CONFIGURATIONS Release)
    set_property(TARGET Vulkan::volk APPEND
            PROPERTY
              IMPORTED_LOCATION_RELEASE "${Vulkan_volk_LIBRARY}")

if (NOT WIN32)
      set_property(TARGET Vulkan::volk APPEND
              PROPERTY
                IMPORTED_LINK_INTERFACE_LIBRARIES dl)
    endif()
  endif()

if (Vulkan_dxc_LIBRARY AND NOT TARGET Vulkan::dxc_lib)
    add_library(Vulkan::dxc_lib STATIC IMPORTED)
    set_property(TARGET Vulkan::dxc_lib
      PROPERTY
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_INCLUDE_DIRS}")
    set_property(TARGET Vulkan::dxc_lib APPEND
      PROPERTY
        IMPORTED_CONFIGURATIONS Release)
    set_property(TARGET Vulkan::dxc_lib APPEND
      PROPERTY
        IMPORTED_LOCATION_RELEASE "${Vulkan_dxc_LIBRARY}")
  endif()

if(Vulkan_dxc_EXECUTABLE AND NOT TARGET Vulkan::dxc_exe)
    add_executable(Vulkan::dxc_exe IMPORTED)
    set_property(TARGET Vulkan::dxc_exe PROPERTY IMPORTED_LOCATION "${Vulkan_dxc_EXECUTABLE}")
  endif()

endif()

if(Vulkan_MoltenVK_FOUND)
  if(Vulkan_MoltenVK_LIBRARY AND NOT TARGET Vulkan::MoltenVK)
    add_library(Vulkan::MoltenVK SHARED IMPORTED)
    set_target_properties(Vulkan::MoltenVK
      PROPERTIES
        INTERFACE_INCLUDE_DIRECTORIES "${Vulkan_MoltenVK_INCLUDE_DIR}"
        IMPORTED_LOCATION "${Vulkan_MoltenVK_LIBRARY}"
    )
  endif()
endif()

unset(_Vulkan_library_name)
unset(_Vulkan_hint_include_search_paths)
unset(_Vulkan_hint_executable_search_paths)
unset(_Vulkan_hint_library_search_paths)

cmake_policy(POP)

XYZ File Manager

Editing: FindVulkan.cmake

Upload File

Create Folder